Quake-C 関連アーカイヴ一式ダウンロード

Title	File Name	Size	Site
Complete Quake-C ver 1.06 package	qc106pac.zip	284KB	ftp://cdrom.com/pub/quake/utils/quakec/
Quake Documentation V 3.4	qcspec34.zip	264KB	ftp://cdrom.com/pub/quake/docs/editing/

		．
		．
		．
void() monster_dog =		//これは犬のentityオブジェクト生成時に呼び出される関数
{
	if (deathmatch)			//ゲームがデスマッチならば犬を削除
	{
		remove(self);
		return;
	}
	precache_model ("progs/h_dog.mdl");		//キャッシュ内へ必要なmodelを読み込み
	precache_model ("progs/dog.mdl");

	precache_sound ("dog/dattack1.wav");	//キャッシュ内へ必要なsoundを読み込み
	precache_sound ("dog/ddeath.wav");
	precache_sound ("dog/dpain1.wav");
	precache_sound ("dog/dsight.wav");
	precache_sound ("dog/idle.wav");

	self.solid = SOLID_SLIDEBOX;		//monster等のSOLIDタイプは殆どSLIDEBOX
	self.movetype = MOVETYPE_STEP;	//犬は地上を歩くのでMOVEタイプはSTEP

	setmodel (self, "progs/dog.mdl");	//使用するmodelを指定

	setsize (self, '-32 -32 -24', '32 32 40');	//犬のサイズを決める
	self.health = 25;			//ここの25を255へ書き換える(体力値)

	self.th_stand = dog_stand1;	//突っ立っている時に呼び出す関数名
	self.th_walk = dog_walk1;	//歩行時に呼び出す関数名
	self.th_run = dog_run1;		//走行時に呼び出す関数名
	self.th_pain = dog_pain;	//攻撃を食らった時に呼び出す関数名
	self.th_die = dog_die;		//死んだ時に呼び出す関数名
	self.th_melee = dog_atta1;	//攻撃時に呼び出す関数名
	self.th_missile = dog_leap1;	//ミサイル接近時に呼び出す関数名

	walkmonster_start();		//犬の活動開始
};

		．
		．
		．
void() T_MissileTouch =		//プレイヤーのロケットが物体に接触した際に呼び出される関数
{
	local float	damg;		//ダメージ値計算のためにローカル変数damgを宣言

	if (other == self.owner)	//もしも接触した物体がロケットを発射した本人だった場合は無視
		return;

	if (pointcontents(self.origin) == CONTENT_SKY)	//ロケットが空へめりこんだらロケットを削除
	{
		remove(self);
		return;
	}

	damg = 100 + random()*20;	//random()は0.0〜1.0間の乱数を返す、ロケットのダメージは100に
					//乱数と20の積を加えたものである
	if (other.health)		//接触した相手に体力があった場合
	{
		if (other.classname == "monster_shambler")	//接触した相手がシャンブラーだった場合
			damg = damg * 0.5;	//ここの0.5を10へ書き換える(ダメージ増)
		T_Damage (other, self, self.owner, damg );	//接触した相手にダメージを与える
	}

	// entity other(接触した相手)に対し、爆風による特定空間内ダメージ処理を行わない
	// 既にロケットが接触した際、ダメージを与えているからである
	T_RadiusDamage (self, self.owner, 120, other);	//特定空間内ダメージ処理(無視する相手にotherを指定)

//	sound (self, CHAN_WEAPON, "weapons/r_exp3.wav", 1, ATTN_NORM);
	self.origin = self.origin - 8*normalize(self.velocity);		//爆発の表示位置を接触地点より8だけ後退

	WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);	//テンポラリentityのネットワークメッセージ送信
	WriteByte (MSG_BROADCAST, TE_EXPLOSION);	//ここで爆発音を指定している
	WriteCoord (MSG_BROADCAST, self.origin_x);	//爆発音発生地点を指定
	WriteCoord (MSG_BROADCAST, self.origin_y);
	WriteCoord (MSG_BROADCAST, self.origin_z);

	BecomeExplosion ();		//ロケットは爆発へ変身
};
		．
		．
		．